Интерпретация во время компиляции, или Альтернативное понимание лямбд в C++11

А про D очень мало информации (в книге Александреску этого нет, на официальном сайте простейший пример). Конструкция mixin — там просто строки, в которых код. Непонятно, можно ли эти строки конструировать программно, если можно — какие операции разрешены для времени компиляции и т.д.

Можно, причем двумя разными способами. Первый — выполнение функций в compile time, второй — через шаблоны. Для примера рассмотрю первый вариант. Практически любые функции, которые не используют IO, указатели и другие низкоуровневые фичи языка можно выполнять на этапе компиляции. Для этого нужно просто использовать функцию в контексте, в котором у нее нет выбора, кроме как выполниться при компиляции (например, присвоить результат к константе enum).

Иллюстрация: есть два энума A и B, нужно сгененрировать switch по элементам первого энума, который поставит в соответствие каждому элементу A элемент в B.

import std.stdio;

enum A
{
    a1,
    a2,
    a3
}

enum B
{
    b1,
    b2,
    b3
}

// Берем два энума и название переменной, для которой будет
// сгенерирован switch
string genSwitch(E1, E2)(string var)
    if(is(E1 == enum) && is(E2 == enum))
{
    // Просим компилятор выдать нам tuple всех элементов типа
    enum E1Members = __traits(allMembers, E1);
    enum E2Members = __traits(allMembers, E2);
    // Проверяем, чтобы их длинны совпадали, проверка во время компиляции
    static assert(E1Members.length == E2Members.length);

    // Используем все обычные средства для работы со строками
    // для генерации свитча
    string s = "final switch("~var~")\n{\n";
    foreach(i, member; E1Members)
    {
        s ~= "\tcase("~E1.stringof~"."~member~"):\n\t{\n";
        s ~= "\t\twriteln("~E2.stringof~"."~E2Members[i]~");\n";
        s ~= "\t\tbreak;\n\t}\n";
    }
    return s~"}";
}

void main()
{
    auto a = A.a2;
    
    // Способ вывести что-нибудь во время компиляции в консоль
    pragma(msg, genSwitch!(A, B)("a"));
    // Встраиваем сгенеренный свитч
    mixin(genSwitch!(A, B)("a"));
}

Во время компиляции увидим:

final switch(a)
{
    case(A.a1):
    {
        writeln(B.b1);
        break;
    }
    case(A.a2):
    {
        writeln(B.b2);
        break;
    }
    case(A.a3):
    {
        writeln(B.b3);
        break;
    }
}

P.S. Это просто иллюстрация. Генерацию через шаблоны того же кода, если интересно, то тоже приведу.

В книжке Александреску делается акцент на том, что строки можно генерировать в compile-time, еще он в качестве примера приводит возможность написания compile-time DSL на D.