Вы не умеете работать с транзакциями

В 1С нет механизма работы с базой данных без транзакций?

По вашей же ссылке во втором абзаце написано обратное. Данная ошибка может возникать при восстановимом исключении на работе с БД. Причем не обязательно на записи, исключение при чтении тоже выкинет "в данной транзакции уже происходили ощибки" при повторном обращении к бд

Она отменится автоматически только в конце серверного вызова, либо когда кто-то выше по стеку не сделает отмену либо фиксацию. Без явной отмены в блоке попытки весь код выше по стеку, выполняемый после вызова данного куска с попыткой будет в открытой поломанной транзакции

ВызватьИсключение ОписаниеОшибки();

лучше не делать, просто ВызватьИсключение достаточно, так будет проброшено исходное исключение. Синтаксис доступен только в блоке catch

На счет паттерна:

1. ЗафиксироватьТранзакцию(); обязательно должен быть в блоке Попытка-Исключение
2. Не должно быть логических операций между НачатьТранзакцию(); и Попытка
3. ОтменитьТранзакцию(); должна быть первой операцией в блоке Исключение-КонецПопытки

ТранзакцияАктивна() не обязательно использовать для начала новой транзакции, читайте документацию по транзакциям. Открытие новой транзакции в существующей — откроет вложенную транзакцию, закрытие — закроет вложенную, но нужна повторная фиксация чтобы закрыть основную (как раз ваш случай), отмена транзакции отменяет все, включая весь стек сложенных.

Весь код приходит в вид:

НачатьТранзакцию(); // Если транзакция открыта - откроется вложенная
Попытка
    ДелаемЧтоТо();
    ЗафиксироватьТранзакцию(); // если это вложенная - произойдет переход к основной, иначе произойдет фиксация в базу
Исключение
    ОтменитьТранзакцию(); // Отменятся все транзакции, даже если это вложенная
    ВызватьИсключение; // Выбросится изначальное исключение
КонецПопытки;

никаких НачатьТранзакцию в глубине стека

Хватит изобретать велосипед, есть пример в стандарте "Перехват исключений в коде"

3.6. При использовании транзакций следует придерживаться следующей схемы обработки исключений в коде на сервере:

// 1. Начало транзакции
НачатьТранзакцию();
Попытка
 // 2. Вся логика блокировки и обработки данных размещается в блоке Попытка-Исключение
 Запрос = Новый Запрос("...");
 Выборка = Запрос.Выполнить().Выбрать();
 Пока Выборка.Следующий() Цикл
  ... 
 КонецЦикла;

 // 3. В самом конце обработки данных выполняется попытка зафиксировать транзакцию
 ЗафиксироватьТранзакцию();
Исключение
 // 4. В случае любых проблем с СУБД, транзакция сначала отменяется...
 ОтменитьТранзакцию();
 // 5. ...затем проблема фиксируется в журнале регистрации...
 ЗаписьЖурналаРегистрации(НСтр("ru = 'Выполнение операции'"), УровеньЖурналаРегистрации.Ошибка,,, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
 // 6. ... после чего, проблема передается дальше вызывающему коду.
 ВызватьИсключение;
КонецПопытки;

Поскольку исключение не отменяет транзакцию сразу, но запрещает успешное завершение транзакции, то все вызовы НачатьТранзакцию, с одной стороны, и ЗафиксироватьТранзакцию или ОтменитьТранзакцию, с другой стороны, должны быть парными.

Отсутствие обработки исключительных ситуаций приводит к зависшим транзакциям и к сложнодиагностируемым ошибкам вида «В этой транзакции уже происходили ошибки» в произвольных местах кода. При этом в случае вложенных операторов НачатьТранзакцию, следует обеспечить вызов всех парных операторов ОтменитьТранзакцию. Для этого в конце блока Исключение необходимо пробросить исключение выше по стеку с помощью ВызватьИсключение (как в примере выше) и соответствующим образом обработать исключение на каждом уровне стека.

На каком основании делается вывод, что ДелаемЧтоТо(); начал и не закончил транзакцию лишь однажды, а если это произошло два или более раз?

Насколько я понял, защита тут от ровно противоположного — вдруг ДелаемЧтоТо() не начинал транзакцию, но ее закончил.